**3.8. Варианты отчетов**

Подсистема «Варианты отчетов» отображает все отчеты раздела на панели отчетов, предоставляет совместный доступ к пользовательским вариантам отчетов, а также универсальные формы для формирования и настройки произвольных отчетов конфигурации.

Варианты отчетов, созданные разработчиком (через конфигуратор), называются предопределенными, а сохраненные пользователем (в режиме 1С:Предприятие) – пользовательскими. Предопределенные варианты отчетов могут быть контекстными или неконтекстными:

* ● контекстные варианты отчетов могут использоваться только в контексте работы с каким-либо объектом программы (например, отчет по сотруднику, подразделению и т. п.). Как правило, такие варианты отчетов открываются из формы объекта и списков;
* ● неконтекстные варианты отчетов могут одинаково открываться из любого места программы (например, из панели отчетов), не требуя передачи контекста. Как правило, такие варианты отчетов открываются из командного интерфейса.

Начальные настройки предопределенных вариантов отчетов зачитываются из метаданных, и их можно изменить на этапе внедрения подсистемы. Для того чтобы изменения в метаданных конфигурации (добавление, изменение отчетов, вариантов отчетов и т.п.) сразу вступили в силу в процессе разработки и отладки, необходимо [обновить данные справочника ВариантыОтчетов](https://its.1c.ru/db/content/bsp301doc/src/3.8.%20%D0%B2%D0%B0%D1%80%D0%B8%D0%B0%D0%BD%D1%82%D1%8B%20%D0%BE%D1%82%D1%87%D0%B5%D1%82%D0%BE%D0%B2.htm?_=1542292879#_обновить_данные_справочника).

Размещение варианта отчета на панели отчетов можно изменить при сохранении или из его карточки. Настройки размещения выводятся в виде дерева подсистем с флажком использования и важностью.

В панели отчетов раздела каждый пользователь может изменить настройки видимости и быстрого доступа к вариантам отчетов под себя, переключившись в режим настройки. Также в панели отчетов предусмотрен поиск по свойствам отчета: наименованию, описанию, наименованиям подсистем (разделов и групп командного интерфейса), полей, отборов и пользовательских настроек.

**Настройка**

Настройка подсистемы состоит из 7 этапов:

1. Подключить хранилище вариантов отчетов.

2. Подключить форму отчета.

3. Подключить подсистему к разделам командного интерфейса.

4. Установить настройки вариантов отчетов.

5. Подключить контекстные отчеты.

6. Установить настройки формы отчета.

7. Обновить данные справочника ВариантыОтчетов.

**Подключить хранилище вариантов отчетов**

Необходимо принять решение по поводу варианта внедрения хранилища подсистемы:

1. Если конфигурация ранее не выпускалась (т. е. пользователи не сохраняли в своих базах никаких вариантов отчетов), то следует выбрать один из двух способов внедрения:

* ● Полный, если к подсистеме необходимо подключить все отчеты конфигурации, а также все внешние (дополнительные) отчеты. Для этого необходимо установить хранилище настроек ХранилищеВариантовОтчетов в свойстве конфигурации «Хранилище вариантов отчетов»;
* ● Частичный, если необходимо подключить подсистему выборочно только для некоторой части отчетов. Для этого необходимо установить хранилище настроек ХранилищеВариантовОтчетов в свойстве Хранилище вариантов отчетов каждого отчета, который нужно подключить к хранилищу подсистемы.

2. Если конфигурация уже выпускалась, т. е. существует вероятность того, что пользователи сохраняли в своих базах варианты отчетов, то следует использовать только Частичный способ внедрения. В этом случае ранее сохраненные пользователями варианты отчетов будут перенесены в хранилище подсистемы автоматически.

В противном случае, если в такой ситуации был выбран сценарий внедрения Полный, подсистема не сможет автоматически перенести ранее сохраненные пользователями варианты отчетов. В этом случае необходимо:

* ● включить в сопроводительную документацию к конфигурации инструкцию (или донести эту информацию другими способами) для администратора (пользователя, который выполняет обновление конфигурации), что он должен запустить обработку перехода перед обновлением;
* ● разработать и включить в состав дистрибутива обработку перехода. Пример подобной обработки входит в состав демонстрационной конфигурации – ВариантыОтчетовПереносВариантовОтчетов.epf.

**Подключить форму отчета**

Необходимо принять решение по поводу варианта внедрения формы отчета:

* ● Полный, если к подсистеме необходимо подключить все отчеты без основной формы. Для этого необходимо указать в свойствах конфигурации общие формы, поставляемые подсистемой:
* ● основная форма отчета – ФормаОтчета;
* ● основная форма настроек отчета – ФормаНастроекОтчета;
* ● основная форма варианта отчета – ФормаВариантаОтчета;
* ● Частичный, если необходимо подключить подсистему выборочно только для части отчетов без основной формы. Для этого необходимо указать в свойствах каждого отчета общие формы, поставляемые подсистемой:
* ● основная форма – ФормаОтчета;
* ● основная форма настроек – ФормаНастроекОтчета;
* ● основная форма варианта – ФормаВариантаОтчета.

Внимание: не поддерживается ситуация, когда отчет подключен только к некоторым из указанных форм. В частности, в случае «Полного» варианта внедрения, если для отчета на СКД определена собственная основная форма, то для него также следует определить собственную форму настроек (либо в свойствах этого отчета указать общую форму ВспомогательнаяФормаНастроекОтчета). Это требование также распространяется на дополнительные и внешние отчеты, использующиеся в конфигурации с «Полным» вариантом внедрения формы отчета.

**Подключить подсистему к разделам командного интерфейса**

Необходимо определить разделы командного интерфейса, в которых должны быть размещены панели отчетов. Рекомендуется выбрать все разделы, для которых предусмотрены отчеты.

* ● Для каждого раздела необходимо cоздать отдельную общую команду для открытия панели отчетов.
* ● Имя команды рекомендуется задавать по шаблону "ПанельОтчетов<ИмяРаздела>", например: "ПанельОтчетовПродажи".
* ● Cиноним команды рекомендуется определять по шаблону "Отчеты по <ПредставлениеРаздела>", например: "Отчеты по продажам".
* ● В обработчике команды необходимо вставить вызов по шаблону:

[Копировать в буфер обмена](javascript:)

&НаКлиенте

Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполнения)

ВариантыОтчетовКлиент.ПоказатьПанельОтчетов("<ИмяРаздела>", ПараметрыВыполнения);

КонецПроцедуры

* Для начальной страницы в первом параметре следует передавать результат выполнения функции ВариантыОтчетовКлиентСервер.ИдентификаторНачальнойСтраницы():

[Копировать в буфер обмена](javascript:)

ВариантыОтчетовКлиент.ПоказатьПанельОтчетов(ВариантыОтчетовКлиентСервер.ИдентификаторНачальнойСтраницы(), ПараметрыВыполнения);

* ● Выбранные разделы необходимо перечислить в процедуре ОпределитьРазделыСВариантамиОтчетов общего модуля ВариантыОтчетовПереопределяемый. В представлениях разделов (используются в качестве заголовков панелей отчетов) рекомендуется указывать синонимы команд, созданных на предыдущем шаге.
* ● Все отчеты выбранных разделов рекомендуется скрыть из панели действий командного интерфейса этих разделов.

**Установить настройки вариантов отчетов**

Настройки вариантов отчетов задаются в процедуре НастроитьВариантыОтчетов общего модуля ВариантыОтчетовПереопределяемый. Настройки можно менять непосредственно в переопределяемом модуле (удобно в небольших конфигурациях) или в модуле менеджера отчета (удобно при совместной разработке и больше соответствует библиотечному подходу). Для этого в процедуре НастроитьВариантыОтчетов общего модуля ВариантыОтчетовПереопределяемый следует разместить вызов модуля менеджера отчета по шаблону:

[Копировать в буфер обмена](javascript:)

ВариантыОтчетов.НастроитьОтчетВМодулеМенеджера(Настройки, Метаданные.Отчеты.ИмяОтчета);

А в модуле менеджера отчета вставить процедуру по шаблону:

[Копировать в буфер обмена](javascript:)

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область ПрограммныйИнтерфейс

// Настройки размещения в панели отчетов.

//

// Параметры:

//   Настройки - Коллекция - Используется для передачи в параметрах вспомогательных методов (см. ниже).

//       Соответствует 1 параметру процедуры ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов().

//   НастройкиОтчета - СтрокаДереваЗначений - Настройки этого отчета,

//       уже сформированные при помощи функции ВариантыОтчетов.ОписаниеОтчета() и готовые к изменению.

//       См. "Свойства для изменения" процедуры ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов().

//

// Описание:

//   См. ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов().

//

// Вспомогательные методы:

// НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "<ИмяВарианта>");

// ВариантыОтчетов.УстановитьРежимВыводаВПанеляхОтчетов(Настройки, НастройкиОтчета, Истина/Ложь);

//

// Примеры:

//

//  1. Установка описания варианта.

// НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "<ИмяВарианта>");

// НастройкиВарианта.Описание = НСтр("ru = '<Описание>'");

//

//  2. Отключение варианта отчета.

// НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "<ИмяВарианта>");

// НастройкиВарианта.Включен = Ложь;

//

Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт

// Код процедуры.

КонецПроцедуры

#КонецОбласти

#КонецЕсли

Объекты НастройкиОтчета и НастройкиВарианта содержат следующие свойства, которые можно менять:

* ● Включен – если установить в Ложь, то вариант отчета не регистрируется в справочнике и как следствие не выводится в панелях отчетов и других формах подсистемы (всегда скрыт от пользователей). При этом вариант отчета остается в конфигурации, и его по-прежнему можно открывать при программном открытии формы отчета. Например, может потребоваться отключение контекстных вариантов отчетов.
* ● Описание – служит подсказкой на панели отчетов и содержит более подробное описание варианта отчета. Описание можно не заполнять для контекстных вариантов отчетов (которые не выводятся в панелях и списках отчетов). В противном случае Описание обязательно для заполнения.
* ● ВидимостьПоУмолчанию – если установить в Ложь, то вариант отчета по умолчанию будет скрыт на панелях отчетов. Скрытый вариант отчета можно вывести на панель отчетов администратору – сразу для всех пользователей (через форму элемента), пользователю – на свою панель отчетов (через режим настройки). Например, может потребоваться скрывать менее частотные варианты отчетов.
* ● Описание – служит подсказкой на панели отчетов и содержит более подробное описание варианта отчета.
* ● Размещение – служит для привязки вариантов отчетов к подсистемам конфигурации. Подсистемы первого уровня считаются разделами, второго и выше – группами. Если вариант включен в раздел, то на панели отчетов он будет выведен без группы. При необходимости для каждой подсистемы можно указать Важность:
* ● Важный – вариант отчета будет выделен жирным шрифтом и размещен в начале группы.
* ● СмТакже – вариант отчета будет выведен внизу панели отчетов, в группе См. также.
* ● ФункциональныеОпции – служит для скрытия вариантов отчетов по функциональным опциям. Содержит массив строк из имен функциональных опций конфигурации. Вариант отчета считается включенным в том случае, если включена одна из функциональных опций отчета (если они указаны) и одна из функциональных опций варианта отчета (если они указаны).
* ● НастройкиДляПоиска – дополнительные сведения для поиска этого варианта отчета. Является структурой со следующими свойствами:
* ● НаименованияПолей – представления полей варианта отчета;
* ● НаименованияПараметровИОтборов – представления настроек варианта отчета;
* ● КлючевыеСлова – дополнительная терминология (в т.ч. специализированная или устаревшая).

Разделитель терминов: Символы.ПС.

* ● ОпределитьНастройкиФормы – включает переопределение настроек формы отчета. Внимание: свойство доступно только для объекта НастройкиОтчета. Если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ОпределитьНастройкиФормы по шаблону:

[Копировать в буфер обмена](javascript:)

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область ПрограммныйИнтерфейс

// Настройки общей формы отчета подсистемы "Варианты отчетов".

//

// Параметры:

//   Форма - УправляемаяФорма, Неопределено - Форма отчета или форма настроек отчета.

//       Неопределено когда вызов без контекста.

//   КлючВарианта - Строка, Неопределено - Имя предопределенного

//       или уникальный идентификатор пользовательского варианта отчета.

//       Неопределено когда вызов без контекста.

//   Настройки - Структура - Настройки общей формы отчета (для изменения).

//       См. возвращаемое значение ОтчетыКлиентСервер.ПолучитьНастройкиОтчетаПоУмолчанию().

//

Процедура ОпределитьНастройкиФормы(Форма, КлючВарианта, Настройки) Экспорт

КонецПроцедуры

#КонецОбласти

#КонецЕсли

Подробнее про изменение настроек формы отчета см. раздел «[Изменить настройки формы отчета](https://its.1c.ru/db/content/bsp301doc/src/3.8.%20%D0%B2%D0%B0%D1%80%D0%B8%D0%B0%D0%BD%D1%82%D1%8B%20%D0%BE%D1%82%D1%87%D0%B5%D1%82%D0%BE%D0%B2.htm?_=1542292879#_изменить_настройки_формы)».

**Подключить контекстные отчеты к объектам конфигурации**

Необходимо принять решение, для каких справочников, документов и других объектов конфигурации разрабатываются контекстные отчеты, и в каких их формах требуется выводить подменю с контекстными отчетами. Например, команда открытия отчета о движениях документа может быть предусмотрена во всех документах, формирующих движения в регистры.

При этом стоит учитывать сценарии подключения команд при помощи расширений конфигурации и дополнительных отчетов. Т.е. если для определенного объекта программы не планируется разрабатывать контекстные отчеты в составе конфигурации, то рекомендуется заблаговременно подключать команды отчетов для этого объекта на тот случай, если такая потребность с высокой степенью вероятности возникнет у разработчиков расширений и дополнительных отчетов для вашей конфигурации.

Для подключения контекстных отчетов к объектам конфигурации следует:

* ● Объекты метаданных, для которых требуется выводить команды отчетов, перечислить в процедуре ОпределитьОбъектыСКомандамиОтчетов модуля ВариантыОтчетовПереопределяемый.
* ● В модуле менеджера каждого из этих объектов, в области ПрограммныйИнтерфейс, определить пустую процедуру ДобавитьКомандыОтчетов по шаблону:

[Копировать в буфер обмена](javascript:)

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область ПрограммныйИнтерфейс

#Область ДляВызоваИзДругихПодсистем

Процедура ДобавитьКомандыОтчетов(КомандыОтчетов, Параметры) Экспорт

КонецПроцедуры

#КонецОбласти

#КонецОбласти

#КонецЕсли

* ● В формах объектов (списков и т.п.) метаданных, в которых требуется выводить подменю Отчеты, встроить подсистему Подключаемые команды. В командную панель рекомендуется добавить подменю для вывода команд отчетов:
* ● Имя: ПодменюОтчеты,
* ● Заголовок: Отчеты,
* ● Вид: Подменю,
* ● Отображение: Картинка.
* ● Картинка: Отчет (стандартная картинка).

Для вывода в подменю Отчеты большого количества команд (более 10) рекомендуется добавить вложенные группы кнопок с суффиксами Важное, Обычное и СмТакже. Например: ПодменюОтчетыВажное, ПодменюОтчетыОбычное и ПодменюОтчетыСмТакже. Тогда разработчики команд контекстных отчетов смогут указывать суффиксы этих групп в свойстве Важность своих команд.

Подробнее о разработке команд контекстных отчетов см. раздел ниже.

**Установить настройки формы отчета**

Настройки формы отчета задаются в процедуре ОпределитьНастройкиФормы модуля объекта отчета. Как определить эту процедуру, уже описано выше. Настройки для изменения передаются трем параметрам этой процедуры и содержат следующие свойства:

* ● ФормироватьСразу – если установить в значение Истина, то отчет будет формироваться после открытия, после выбора пользовательских настроек и после выбора другого варианта отчета. По умолчанию – Ложь.
* ● ВыводитьСуммуВыделенныхЯчеек – если установить в значение Ложь, то в отчете не будет выводиться поле с автоматически рассчитываемой суммой выделенных ячеек. По умолчанию – Истина.
* ● РазрешеноИзменятьСтруктуру – если установить в значение Ложь, то в настройках отчета будет скрыта вкладка "Структура". По умолчанию – Истина. По умолчанию вкладка "Структура" показыватеся для отчетов на СКД: в расширенном режиме, а также в простом режиме, если в пользовательские настройки выведены флажки использования группировок.
* ● РазрешеноИзменятьВарианты – если установить в значение Ложь, то в форме отчета и настроек скрываются кнопки изменения вариантов этого отчета. Если у текущего пользователя нет прав СохранениеДанныхПользователя и Добавление справочника ВариантыОтчетов, то принудительно устанавливается в Ложь. По умолчанию – Истина.
* ● Печать – Структура – параметры печати табличного документа (могут переопределяться пользователем):
* ● ПолеСверху – Число – отступ сверху при печати (в миллиметрах);
* ● ПолеСлева – Число – отступ слева при печати (в миллиметрах);
* ● ПолеСнизу – Число – отступ снизу при печати (в миллиметрах);
* ● ПолеСправа – Число – отступ справа при печати (в миллиметрах);
* ● ОриентацияСтраницы – ОриентацияСтраницы – «Портрет» или «Ландшафт»;
* ● АвтоМасштаб – Булево – автоматически подгонять масштаб под размер страницы;
* ● МасштабПечати – Число – масштаб изображения (в процентах).
* ● События – Структура – события, для которых определены обработчики в модуле объекта отчета (обработчики событий рекомендуется определять в области ПрограммныйИнтерфейс, после процедуры ОпределитьНастройкиФормы):
* ● ПриСозданииНаСервере – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПриСозданииНаСервере по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается в обработчике одноименного события формы отчета после выполнения кода формы.

//

// Параметры:

//   Форма - УправляемаяФорма - Форма отчета.

//   Отказ - Булево - Признак отказа от создания формы.

//      См. описание одноименного параметра "УправляемаяФорма.ПриСозданииНаСервере" в синтакс-помощнике.

//   СтандартнаяОбработка - Булево - Признак выполнения стандартной (системной) обработки события.

//      См. описание одноименного параметра "УправляемаяФорма.ПриСозданииНаСервере" в синтакс-помощнике.

//

// См. также:

//   Процедура для вывода добавленных команд в форму: ОтчетыСервер.ВывестиКоманду().

//   Глобальный обработчик этого события: ОтчетыПереопределяемый.ПриСозданииНаСервере().

//

// Пример добавления команды:

// Команда = Форма.Команды.Добавить("<ИмяКоманды>");

// Команда.Действие  = "Подключаемый\_Команда";

// Команда.Заголовок = НСтр("ru = '<Представление команды...>'");

// ОтчетыСервер.ВывестиКоманду(Форма, Команда, "<ВидГруппы>");

// Обработчик команды пишется в процедуре ОтчетыКлиентПереопределяемый.ОбработчикКоманды.

//

Процедура ПриСозданииНаСервере(Форма, Отказ, СтандартнаяОбработка) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПередЗагрузкойНастроекВКомпоновщик – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПередЗагрузкойНастроекВКомпоновщик по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается перед загрузкой новых настроек. Используется для изменения схемы компоновки.

//   Например, если схема отчета зависит от ключа варианта или параметров отчета.

//   Чтобы изменения схемы вступили в силу следует вызывать метод ОтчетыСервер.ПодключитьСхему().

//

// Параметры:

//   Контекст - Произвольный -

//       Параметры контекста, в котором используется отчет.

//       Используется для передачи в параметрах метода ОтчетыСервер.ПодключитьСхему().

//   КлючСхемы - Строка -

//       Идентификатор текущей схемы компоновщика настроек.

//       По умолчанию не заполнен (это означает что компоновщик инициализирован на основании основной схемы).

//       Используется для оптимизации, чтобы переинициализировать компоновщик как можно реже).

//       Может не использоваться, если переинициализация выполняется безусловно.

//   КлючВарианта - Строка, Неопределено -

//       Имя предопределенного или уникальный идентификатор пользовательского варианта отчета.

//       Неопределено, когда вызов для варианта расшифровки или без контекста.

//   НовыеНастройкиКД - НастройкиКомпоновкиДанных, Неопределено -

//       Настройки варианта отчета, которые будут загружены в компоновщик настроек после его инициализации.

//       Неопределено, когда настройки варианта не надо загружать (уже загружены ранее).

//   НовыеПользовательскиеНастройкиКД - ПользовательскиеНастройкиКомпоновкиДанных, Неопределено -

//       Пользовательские настройки, которые будут загружены в компоновщик настроек после его инициализации.

//       Неопределено, когда пользовательские настройки не надо загружать (уже загружены ранее).

//

// Примеры:

// 1. Компоновщик отчета инициализируется на основании схемы из общих макетов:

// Если КлючСхемы <> "1" Тогда

// КлючСхемы = "1";

// СхемаКД = ПолучитьОбщийМакет("МояОбщаяСхемаКомпоновки");

// ОтчетыСервер.ПодключитьСхему(ЭтотОбъект, Контекст, СхемаКД, КлючСхемы);

// КонецЕсли;

//

// 2. Схема зависит от значения параметра, выведенного в пользовательские настройки отчета:

// Если ТипЗнч(НовыеПользовательскиеНастройкиКД) = Тип("ПользовательскиеНастройкиКомпоновкиДанных") Тогда

// ПолноеИмяОбъектаМетаданных = "";

// Для Каждого ЭлементКД Из НовыеПользовательскиеНастройкиКД.Элементы Цикл

// Если ТипЗнч(ЭлементКД) = Тип("ЗначениеПараметраНастроекКомпоновкиДанных") Тогда

// ИмяПараметра = Строка(ЭлементКД.Параметр);

// Если ИмяПараметра = "ОбъектМетаданных" Тогда

// ПолноеИмяОбъектаМетаданных = ЭлементКД.Значение;

// КонецЕсли;

// КонецЕсли;

// КонецЦикла;

// Если КлючСхемы <> ПолноеИмяОбъектаМетаданных Тогда

// КлючСхемы = ПолноеИмяОбъектаМетаданных;

// СхемаКД = Новый СхемаКомпоновкиДанных;

// // Наполнение схемы...

// ОтчетыСервер.ПодключитьСхему(ЭтотОбъект, Контекст, СхемаКД, КлючСхемы);

// КонецЕсли;

// КонецЕсли;

//

Процедура ПередЗагрузкойНастроекВКомпоновщик(Контекст, КлючСхемы, КлючВарианта, НовыеНастройкиКД, НовыеПользовательскиеНастройкиКД) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПередЗагрузкойВариантаНаСервере – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПередЗагрузкойВариантаНаСервере по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается в обработчике одноименного события формы отчета после выполнения кода формы.

//

// Параметры:

//   Форма - УправляемаяФорма - Форма отчета.

//   НовыеНастройкиКД - НастройкиКомпоновкиДанных - Настройки для загрузки в компоновщик настроек.

//

// См. также:

//   "Расширение управляемой формы для отчета.ПриЗагрузкеВариантаНаСервере" в синтакс-помощнике.

//

Процедура ПередЗагрузкойВариантаНаСервере(Форма, НовыеНастройкиКД) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПриЗагрузкеВариантаНаСервере – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПриЗагрузкеВариантаНаСервере по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается в обработчике одноименного события формы отчета после выполнения кода формы.

//

// Параметры:

//   Форма - УправляемаяФорма - Форма отчета.

//   НовыеНастройкиКД - НастройкиКомпоновкиДанных - Настройки для загрузки в компоновщик настроек.

//

// См. также:

//   "Расширение управляемой формы для отчета.ПриЗагрузкеВариантаНаСервере" в синтакс-помощнике.

//

Процедура ПриЗагрузкеВариантаНаСервере(Форма, НовыеНастройкиКД) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПриЗагрузкеПользовательскихНастроекНаСервере – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПриЗагрузкеПользовательскихНастроекНаСервере по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается в обработчике одноименного события формы отчета после выполнения кода формы.

//

// Параметры:

//   Форма - УправляемаяФорма - Форма отчета.

//   НовыеПользовательскиеНастройкиКД - ПользовательскиеНастройкиКомпоновкиДанных -

//       Пользовательские настройки для загрузки в компоновщик настроек.

//

// См. также:

//   "Расширение управляемой формы для отчета.ПриЗагрузкеПользовательскихНастроекНаСервере"

//    в синтакс-помощнике.

//

Процедура ПриЗагрузкеПользовательскихНастроекНаСервере(Форма, НовыеПользовательскиеНастройкиКД) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПередЗаполнениемПанелиБыстрыхНастроек – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПередЗаполнениемПанелиБыстрыхНастроек по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается до перезаполнения панели настроек формы отчета.

//

// Параметры:

//   Форма - УправляемаяФорма - Форма отчета.

//   ПараметрыЗаполнения - Структура - Параметры, которые будут загружены в отчет.

//

Процедура ПередЗаполнениемПанелиБыстрыхНастроек(Форма, ПараметрыЗаполнения) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПослеЗаполненияПанелиБыстрыхНастроек – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПослеЗаполненияПанелиБыстрыхНастроек по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается после перезаполнения панели настроек формы отчета.

//

// Параметры:

//   Форма - УправляемаяФорма - Форма отчета.

//   ПараметрыЗаполнения - Структура - Параметры, которые будут загружены в отчет.

//

Процедура ПослеЗаполненияПанелиБыстрыхНастроек(Форма, ПараметрыЗаполнения) Экспорт

// Обработка события.

КонецПроцедуры

* ● КонтекстныйВызовСервера – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру КонтекстныйВызовСервера по шаблону:

[Копировать в буфер обмена](javascript:)

// Обработчик контекстного вызова сервера.

//   Позволяет выполнить контекстный вызов сервера когда это требуется из клиентского общего модуля.

//   Например, из ОтчетыКлиентПереопределяемый.ОбработчикКоманды().

//

// Параметры:

//   Форма  - УправляемаяФорма

//   Ключ      - Строка    - Ключ операции, которую необходимо выполнить в контекстном вызове.

//   Параметры - Структура - Параметры вызова сервера.

//   Результат - Структура - Результат работы сервера, возвращается на клиент.

//

// См. также:

//   ОбщаяФорма.ФормаОтчета.ВыполнитьКонтекстныйВызовСервера().

//

Процедура КонтекстныйВызовСервера(Форма, Ключ, Параметры, Результат) Экспорт

// Обработка события.

КонецПроцедуры

* ● ПриОпределенииПараметровВыбора – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ПриОпределенииПараметровВыбора по шаблону:

[Копировать в буфер обмена](javascript:)

// Вызывается в форме отчета перед выводом настройки.

//   Подробнее - см. ОтчетыПереопределяемый.ПриОпределенииПараметровВыбора().

//

Процедура ПриОпределенииПараметровВыбора(Форма, СвойстваНастройки) Экспорт

// Обработка события.

КонецПроцедуры

* ● ДополнитьСвязиОбъектовМетаданных – если установить в значение Истина, то в модуле объекта отчета следует определить процедуру ДополнитьСвязиОбъектовМетаданных по шаблону:

[Копировать в буфер обмена](javascript:)

// Дополнительные связи настроек этого отчета.

//   Подробнее - см. ОтчетыПереопределяемый.ДополнитьСвязиОбъектовМетаданных().

//

Процедура ДополнитьСвязиОбъектовМетаданных(СвязиОбъектовМетаданных) Экспорт

// Обработка события.

КонецПроцедуры

Для глобального переопределения поведения универсальной формы отчета,  часть серверных событий  представлена в модуле ОтчетыПереопределяемый.

Процедуры для переопределения поведения клиентских событий, возникающих в универсальной форме отчета, представлены в модуле ОтчетыКлиентПереопределяемый.

В области ПрограммныйИнтерфейс модулей ОтчетыКлиент и ОтчетыСервер представлены вспомогательные процедуры, которые можно вызывать из обработчиков событий формы отчета и при формировании отчета.

**Обновить данные справочника ВариантыОтчетов**

Внимание. Для того чтобы изменения в метаданных конфигурации (добавление, изменение отчетов, вариантов отчетов и т.п.) вступили в силу, необходимо обновить данные справочника ВариантыОтчетов. В большинстве случаев он обновляется автоматически при каждом изменении номера версии конфигурации – в процессе обновления или первоначального заполнения информационной базы. При ведении разработки и отладки конфигурации его рекомендуется обновлять вручную, подробнее см. раздел «[Обновление вспомогательных данных во время разработки](https://its.1c.ru/db/content/bsp301doc/src/3.4.%20базовая%20функциональность.htm?_=1542292879#_обновление_вспомогательных_данных)».

**Особые случаи внедрения подсистемы**

* ● [Внедрение подсистем «Варианты отчетов» без подсистемы «Управление доступом»](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистем_«варианты).

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы нужно использовать роли, приведенные ниже.

Таблица 3.16.

| № | Роли и их назначение |
| --- | --- |
| 1. 1. | ПолныеПрава (из подсистемы «Базовая функциональность»)  Администрирование вариантов отчетов |
| 1. 2. | ДобавлениеИзменениеВариантовОтчетов  Администрирование вариантов отчетов.  Если у пользователя нет права СохранениеДанныхПользователя, то отключаются все возможности по сохранению настроек подсистемы |
| 1. 3. | ДобавлениеИзменениеЛичныхВариантовОтчетов  Добавление и изменение своих вариантов отчетов (доступных только автору).  Просмотр общих вариантов отчетов (доступных всем пользователям).  Если у пользователя нет права СохранениеДанныхПользователя, то отключаются все возможности по сохранению настроек подсистемы |
| 1. 4. | ЧтениеВариантовОтчетов  Аудит вариантов отчетов.  Просмотр любых вариантов отчетов без права изменения |
| 1. 5. | БазовыеПраваБСП или БазовыеПраваВнешнихПользователейБСП (из подсистемы «Базовая функциональность»)  Просмотр общих вариантов отчетов (доступных всем пользователям) |
| 1. 6. | ИспользованиеУниверсальногоОтчета  Доступ к отчету Универсальный отчет |

**Использование при разработке конфигурации**

Для того чтобы изменения в метаданных конфигурации (добавление, изменение отчетов, вариантов отчетов и т.п.) вступили в силу, необходимо [обновить данные справочника ВариантыОтчетов](https://its.1c.ru/db/content/bsp301doc/src/3.8.%20%D0%B2%D0%B0%D1%80%D0%B8%D0%B0%D0%BD%D1%82%D1%8B%20%D0%BE%D1%82%D1%87%D0%B5%D1%82%D0%BE%D0%B2.htm?_=1542292879#_обновить_данные_справочника). В редких случаях для этого может потребоваться разработать свой обработчик обновления в прикладной конфигурации.

При необходимости перезаполнения предопределенных вариантов отчетов можно воспользоваться процедурой Обновить общего модуля ВариантыОтчетов. Например, это может потребоваться при изменении настроек программы, если некоторые варианты отчетов отключаются по условиям в зависимости от настроек программы.

При необходимости сбросить пользовательские настройки отчетов можно воспользоваться процедурой СброситьПользовательскиеНастройки общего модуля ВариантыОтчетов. Например, это может потребоваться чтобы «пробросить» изменения в настройках вариантов отчетов пользователям этого варианта.

В случае если у варианта отчета был изменен ключа, его следует указать в процедуре ЗарегистрироватьИзмененияКлючейВариантовОтчетов общего модуля ВариантыОтчетовПереопределяемый.

**Разработка команд контекстных отчетов**

Для разработки контекстных отчетов в конфигурации предварительно должна быть выполнена настройка тех объектов (справочников, документов, и т.п.), к которым эти отчеты подключаются – см. раздел [Подключить контекстные отчеты к объектам конфигурации](https://its.1c.ru/db/content/bsp301doc/src/3.8.%20%D0%B2%D0%B0%D1%80%D0%B8%D0%B0%D0%BD%D1%82%D1%8B%20%D0%BE%D1%82%D1%87%D0%B5%D1%82%D0%BE%D0%B2.htm?_=1542292879#_подключить_контекстные_отчеты).

Команды отчетов, выводимые в конкретных справочниках, документах и других объектах конфигурации, задаются в процедуре [ДобавитьКомандыОтчетов](https://its.1c.ru/db/content/bsp301doc/src/3.8.%20%D0%B2%D0%B0%D1%80%D0%B8%D0%B0%D0%BD%D1%82%D1%8B%20%D0%BE%D1%82%D1%87%D0%B5%D1%82%D0%BE%D0%B2.htm?_=1542292879#_изменить_настройки_формы_1) модуля менеджера этого объекта метаданных. Например:

[Копировать в буфер обмена](javascript:)

// Определяет список команд отчетов.

//

// Параметры:

//   КомандыОтчетов - ТаблицаЗначений - Таблица с командами отчетов. Для изменения.

//       См. описание 1 параметра процедуры ВариантыОтчетовПереопределяемый.ПередДобавлениемКомандОтчетов().

//   Параметры - Структура - Вспомогательные параметры. Для чтения.

//       См. описание 2 параметра процедуры ВариантыОтчетовПереопределяемый.ПередДобавлениемКомандОтчетов().

//

Процедура ДобавитьКомандыОтчетов(КомандыОтчетов, Параметры) Экспорт

Если ПравоДоступа("Просмотр", Метаданные.Отчеты.МестаИспользованияСсылок) Тогда

Команда = КомандыОтчетов.Добавить();

...

КонецЕсли;

КонецПроцедуры

Команды контекстных отчетов, выводимые сразу во всех (или во многих) объектах метаданных, рекомендуется описывать в процедуре ПередДобавлениемКомандОтчетов общего модуля ВариантыОтчетовПереопределяемый. Например:

[Копировать в буфер обмена](javascript:)

Процедура ПередДобавлениемКомандОтчетов(КомандыОтчетов, Параметры, СтандартнаяОбработка) Экспорт

Если ПравоДоступа("Просмотр", Метаданные.Отчеты.МестаИспользованияСсылок) Тогда

Команда = КомандыОтчетов.Добавить();

Команда.Представление      = НСтр("ru = 'Места использования'");

Команда.МножественныйВыбор = Истина;

Команда.ИмяПараметраФормы  = "Отбор.НаборСсылок";

Команда.КлючВарианта       = "Основной";

Команда.Менеджер           = "Отчет.МестаИспользованияСсылок";

КонецЕсли;

КонецПроцедуры

Кроме того, команды отчетов можно задавать в самих отчетах конфигурации (и в отчетах расширений конфигурации). Для этого отчет нужно включить в состав подсистемы ПодключаемыеОтчетыИОбработки и в его модуле менеджера в области ПрограммныйИнтерфейс определить процедуры ПриОпределенииНастроек и ДобавитьКомандыЗаполнения. Подробнее см. пукнт [Подключение отчетов и обработок к механизмам конфигурации](https://its.1c.ru/db/content/bsp301doc/src/3.39.%20подключаемые%20команды.htm?_=1542292879#_подключение_отчетов_и_1) документации подсистемы [Подключаемые команды](https://its.1c.ru/db/content/bsp301doc/src/3.39.%20подключаемые%20команды.htm?_=1542292879#_подключаемые_команды). Пример:

[Копировать в буфер обмена](javascript:)

#Область ПрограммныйИнтерфейс

// Определяет состав программного интерфейса для интеграции с конфигурацией.

//

// Параметры:

//   Настройки - Структура - Настройки интеграции этого объекта.

//       См. возвращаемое значение функции ПодключаемыеКоманды.НастройкиПодключаемыхОтчетовИОбработок().

//

Процедура ПриОпределенииНастроек(Настройки) Экспорт

Настройки.Размещение.Добавить(Метаданные.Документы.ИмяДокумента);

Настройки.ДобавитьКомандыОтчетов = Истина;

КонецПроцедуры

// Определяет список команд отчетов.

//

// Параметры:

//   КомандыОтчетов - ТаблицаЗначений - Таблица с командами отчетов. Для изменения.

//       См. описание 1 параметра процедуры ВариантыОтчетовПереопределяемый.ПередДобавлениемКомандОтчетов().

//   Параметры - Структура - Вспомогательные параметры. Для чтения.

//       См. описание 2 параметра процедуры ВариантыОтчетовПереопределяемый.ПередДобавлениемКомандОтчетов().

//

Процедура ДобавитьКомандыОтчетов(КомандыОтчетов, Параметры) Экспорт

КонецПроцедуры

#КонецОбласти

Примечание

Для команд отчетов, добавленных в процедуре ДобавитьКомандыОтчетов, подключенной указанного выше образом, заполнение параметра Менеджер не обязательно.

Поставка команд отчетов в отчетах конфигурации рекомендуется в тех случаях, когда команды обслуживают сразу несколько объектов (набор обслуживаемых объектов является группирующим признаком для таких команд).

Процедура ДобавитьКомандыОтчетов отчетов, подключенных по такой технологии, вызывается для всех объектов метаданных, указанных в параметре Размещение процедуры ПриОпределенииНастроек.

Таблица 3.17. Колонки таблицы "КомандыОтчетов"

| Параметр | Тип | Описание |
| --- | --- | --- |
| Идентификатор (необязательный) | Строка | Идентификатор команды, который используется для идентификации команды и определения имени команды в форме.  Если идентификатор не указан, то имя команды будет определено автоматически. |
| Представление (обязательный) | Строка | Представление команды в форме. Пример:  [Копировать в буфер обмена](javascript:)  Команда.Представление = НСтр("ru = 'Заполнить ТТН'"); |
| Важность (необязательный) | Строка | Краткое имя (суффикс) группы в подменю, в которой следует вывести эту команду. Допустимо использовать: "Важное", "Обычное" и "СмТакже". |
| Порядок  (необязательный) | Число | Значение от 1 до 100, указывающее порядок размещения команды по отношению к другим командам. Сортировка команд осуществляется сначала по полю Порядок, затем по представлению.  Значение по умолчанию: 50. |
| СочетаниеКлавиш (необязательный) | СочетаниеКлавиш | Сочетание клавиш для быстрого вызова команды. |
| Настройки видимости: | | |
| ТипПараметра (необязательный) | ОписаниеТипов | Типы объектов, для которых предназначена эта команда. Используется, когда обработка (или другой поставщик команд) подключена к нескольким объектам конфигурации, для уточнения списка объектов, к которым подключена конкретная команда. |
| ВидимостьВФормах (необязательный) | Строка | Имена форм через запятую, в которых должна отображаться команда. Используется для уточнения состава форм, к которым подключена конкретная команда. Если параметр не указан, то команда будет отображаться во всех формах. Пример:  [Копировать в буфер обмена](javascript:)  Команда.ВидимостьВФормах = "ФормаДокумента" |
| ФункциональныеОпции  (необязательный) | Строка | Имена функциональных опций через запятую, определяющих видимость команды. |
| УсловияВидимости (необязательный) | Массив | Определяет видимость команды в зависимости от контекста.  Для регистрации условий следует использовать процедуру ПодключаемыеКоманды.ДобавитьУсловиеВидимостиКоманды().  Условия объединяются по "И". |
| ИзменяетВыбранныеОбъекты (необязательный) | Булево | Определяет доступность команды в ситуации, когда у пользователя нет прав на изменение объекта. Если Истина, то кнопка будет недоступна. Значение по умолчанию: Ложь. |
| Настройки процесса выполнения: | | |
| МножественныйВыбор (необязательный) | Булево | Если Истина, то команда поддерживает множественный выбор и в 1 параметре обработчика команды будет передан массив ссылок.  Если Ложь, то команда поддерживает только одиночный выбор и в 1 параметре обработчика команды будет передана 1 ссылка. |
| РежимЗаписи (необязательный) | Строка | Настройки дополнительных проверок и действий, связанных с записью объекта (выполняются перед обработчиком команды).  ● "НеЗаписывать" - Объект не записывается, а в параметрах обработчика вместо ссылок передается вся форма. В этом режиме рекомендуется работать напрямую с формой, которая передается в структуре 2 параметра обработчика команды.  ● "ЗаписыватьТолькоНовые" - Записывать только новые объекты.  ● "Записывать" - Записывать новые и модифицированные объекты.  ● "Проводить" - Проводить документы.  Пример:  [Копировать в буфер обмена](javascript:)  Команда.РежимЗаписи = "НеЗаписывать";  Перед записью и проведением у пользователя запрашивается подтверждение. Значение по умолчанию: "Записывать". |
| ТребуетсяРаботаСФайлами (необязательный) | Булево | Если Истина, то в веб-клиенте перед выполнением команды предлагается установить расширение работы с файлами. |
| Настройки обработчика: | | |
| Менеджер (необязательный) | Строка | Полное имя отчета, отвечающего за выполнение команды.  Если ИмяФормы и Обработчик не указаны, то открывается основная форма отчета с параметрами, соответствующими контекстному режиму работы отчета (их дублирование в структуре ПараметрыФормы не требуется). |
| ИмяФормы (обязательный если не указан Обработчик) | Строка | Имя формы, которую требуется открыть или получить для выполнения команды.  Если Обработчик не указан, то у формы вызывается метод "Открыть". |
| КлючВарианта (необязательный) | Строка | Имя варианта отчета, открываемого при выполнении команды. |
| ИмяПараметраФормы (необязательный) | Строка | Имя параметра формы, в который следует передать ссылку или массив ссылок. |
| ПараметрыФормы (необязательный) | Структура, Неопределено | Параметры формы, указанной в ИмяФормы. |
| Обработчик (обязательный если не указано ИмяФормы) | Строка | Имя процедуры, обрабатывающей основное действие команды.  Пример № 1 - обработчик размещен в общем модуле:  [Копировать в буфер обмена](javascript:)  Команда.Обработчик = "ПродажиКлиент.ВвестиСчетФактуру";  Пример № 2 - обработчик размещен в модуле формы или менеджера:  [Копировать в буфер обмена](javascript:)  Команда.Обработчик = "ЗаполнитьТТН";  Если ИмяФормы заполнено, то в модуле указанной формы ожидается клиентская процедура по шаблону:  [Копировать в буфер обмена](javascript:)  &НаКлиенте  Процедура <ИмяПроцедуры>(<ИмяПараметраКоманды>, ПараметрыВыполнения) Экспорт  // Код обработчика команды.  КонецПроцедуры  Если ИмяФормы не заполнено, то в модуле менеджера объекта, указанного в Менеджер, ожидается серверная процедура по шаблону:  [Копировать в буфер обмена](javascript:)  Процедура <ИмяПроцедуры>(<ИмяПараметраКоманды>, ПараметрыВыполнения) Экспорт  // Код обработчика команды.  КонецПроцедуры  Имя 1го параметра обработчика команды <ИмяПараметраКоманды> рекомендуется задавать в соответствии с типами объектов, для которых предназначена команда. Также следует учитывать, что тип этого параметра зависит от настройки МножественныйВыбор. Если МножественныйВыбор = Истина, тогда передается массив ссылок, в противном случае передается ссылка. Например, если команда предназначена для заполнения документов "Счет на оплату" и МножественныйВыбор включен, то параметр можно называть "МассивСчетовНаОплату" или "СчетаНаОплату". Если МножественныйВыбор отключен, то параметр можно назвать "СчетНаОплату" или "СсылкаСчетаНаОплату".  2й параметр обработчика команды ПараметрыВыполнения имеет тип "Структура" со следующими полями:  ● ОписаниеКоманды - Структура - Описание команды (ключи соответствуют колонкам этой таблицы).  ● Идентификатор - Строка - Идентификатор команды.  ● Представление - Строка - Представление команды в форме.  ● ДополнительныеПараметры - Неопределено, ФиксированнаяСтруктура - Дополнительные параметры команды.  ● Форма - УправляемаяФорма - Форма, из которой вызвана команда.  ● ЭтоФормаОбъекта - Булево - Истина, если команда вызвана из формы объекта.  ● Источник - ТаблицаФормы, ДанныеФормыСтруктура - Объект или список формы с полем "Ссылка". |
| ДополнительныеПараметры (необязательный) | Структура, Неопределено | Дополнительные параметры, которые могут быть считаны в обработчике команды. |

См. также пример реализации команды контекстного отчета в отчете расширения Демо: Подключаемые команды в демонстрационной базе.

Если контекстные отчеты не требуется выводить в панелях отчетов и в списках отчетов, то при [настройке вариантов этих отчетов](https://its.1c.ru/db/content/bsp301doc/src/3.8.%20%D0%B2%D0%B0%D1%80%D0%B8%D0%B0%D0%BD%D1%82%D1%8B%20%D0%BE%D1%82%D1%87%D0%B5%D1%82%D0%BE%D0%B2.htm?_=1542292879#_изменить_настройки_вариантов), следует установить им в свойстве Включен значение Ложь.

**Настройка обмена данными**

Для настройки обмена данными следует руководствоваться общими правилами.

В планы обмена распределенной информационной базы (РИБ) рекомендуется включать все объекты метаданных подсистемы, кроме:

* ● справочника ПредопределенныеВариантыОтчетовРасширений,
* ● регистра сведений ПредопределенныеВариантыОтчетовВерсийРасширений.

Из остальных планов обмена (не РИБ) рекомендуется исключать следующие объекты метаданных:

* ● справочник ПредопределенныеВариантыОтчетовРасширений,
* ● регистр сведений ПредопределенныеВариантыОтчетовВерсийРасширений.